View source for LlGetOwner

==Function: key llGetOwner( );==
Returns a key that is the object owner's [[UUID]].<br><br>
'''Caveats'''<br>
• When the owner of an object changes, code that depends on this function's return value will not automatically update for the new owner or be automatically re-evaluated.<br>
-• This requires the reregistration of [[listens]] and [[requesting of permissions]] from the new owner as needed.<br>
--• This is not limited to listens and permissions but anything that caches the return value, it is up to the programmer to work around this limitation. <br>
-• Detection of owner change can be achieved with the [[changed]] event in conjunction with the [[CHANGED_OWNER]] flag (see the second example) or by storing the old value and periodically (e.g. in on_rez) checking if it has changed. Both techniques are valid though the latter will not detect the sale of the object if it is sold with "sell original" in-world and not picked up. <br><br>
'''Examples''' <br>
{|border="1" cellpadding="5" cellspacing="0"
|<source lang="lsl">
llOwnerSay( (string)llGetOwner()); // speaks in chat the "key" (UUID code) of the avatar.
llOwnerSay( llKey2Name(llGetOwner())); // speaks in chat the name of the owner if in the sim.

default
{
    state_entry()
    {
        llInstantMessage(llGetOwner(), "Only you can hear me. Isn't that eerie.");
    }
 
    changed(integer change)
    {
        if (change & CHANGED_OWNER)
            llResetScript();
    }
}
</source>
|}
<br>
'''Notes''' <br>
To retrieve the owners name while the owner is in the region use [[llKey2Name]], [[llRequestAgentData]] should be used when the owner is not in the region. <br> <br>
The one problem many coders come up against is that previously-activated events referring to the owner don't automatically change when the owner changes. The most often-seen result is a listen registered to owner will continue to listen to the PREVIOUS owner rather than the CURRENT owner. It is often confused as a bug in [[llGetOwner]] or [[llListen]] it is not in fact a bug but part of the design. There are several ways of working around this problem. The easy solution is to reset the script when owner changes or it is rezzed. The easy solution is not always the right solution. <br> <br>
There are two ways to detect if the owner has changed, the most reliable is to use the [[changed]] event. <br>
{|border="1" cellpadding="5" cellspacing="0"
|<source lang="lsl">
changed(integer change)
{
    if (change & CHANGED_OWNER)//if owner changes, reset the script.
        llResetScript();
}
</source>
|}
In many applications resetting the script when the object is rezzed is an adequate and easy solution.
{|border="1" cellpadding="5" cellspacing="0"
|<source lang="lsl">
on_rez(integer start_param)
{ //when the object is rezzed, reset the script.
    llResetScript();
}
</source>
|}
<br>
Resetting the script is not appropriate if the script needs to keep it's data when it's ownership is transfered or if script startup is slow, in these situations listens will need to be re-keyed to the new owner along with any other owner specific code, like who the script is supposed to be animating.<br><br>
The [[on_rez]] and [[changed]] events can be harnessed to reinitialize owner specific code every time the object is rezzed or changes owner.<br><br>
{|border="1" cellpadding="5" cellspacing="0"
|<source lang="lsl">
integer listen_handle;
 
init()
{
    key owner = llGetOwner();
    llListenRemove(listen_handle);
    listen_handle = llListen(0, "", owner, "");
    llRequestPermissions(owner, PERMISSION_TRIGGER_ANIMATION);
}
 
default
{
    state_entry()
    {
        init();
        //insert additional startup code here that doesn't need to run each rez/owner change
        //for example, reading settings from a notecard
    }
 
    on_rez(integer start)
    {
        init();
    }
 
    changed(integer change)
    {
        if (change & CHANGED_OWNER)
            init();
    }
 
    run_time_permissions(integer perm)
    {//always use the run_time_permissions event with llRequestPermissions, never assume
        if(perm & PERMISSION_TRIGGER_ANIMATION)
        {
            //setup your animation code here, start your timers, etc.
            llOwnerSay("I have animation permissions");
        }
    }
}
</source>
|}
<br>
See Also <br>
'''Functions'''  <br>
•  	[[llGetCreator]] 	 <br>		
•  	[[llGetOwnerKey]] 		 <br>	
•  	[[llDetectedOwner]]          <br> <br>