LlDetectedTouchFace

Function: integer llDetectedTouchFace( integer index );

Returns an integer that is the index of the face the avatar clicked on.
• integer index – Index of detection information
index does not support negative indexes.
For the touch category of events only. The prim that was touched may not be the prim receiving the event, use llDetectedLinkNumber to check for this; likewise you can use llDetectedTouchFace to determine which face was touched.

Caveats
TOUCH_INVALID_FACE is returned when...

• The avatar's viewer does not support face touch detection.
• The touch has moved off the surface of the prim.
• The triggering event is not a touch event.

Examples

default {

   touch_start(integer num_detected) {
       integer i;
       for (i = 0; i < num_detected; i++) {
           integer touchedFace = llDetectedTouchFace(i);      

           if (touchedFace == -1) {
               llWhisper(0, "Sorry, your viewer doesn't support touched faces.");
           }
           else {
               // Store away the original color
               vector oldColor = llGetColor(touchedFace);

               // Flash white and black on the touched face
               llSetColor(<1., 1., 1.>, touchedFace);
               llSleep(0.1);
               llSetColor(<0., 0., 0.>, touchedFace);
               llSleep(0.1);

               // Put the color back to how we found it.
               llSetColor(oldColor, touchedFace);
           } // if ...
       } // for ...
   } // touch_start

} </source>

See Also
Events
• touch_start
• touch
• touch_end
Functions
• llDetectedLinkNumber
• llDetectedTouchST
• llDetectedTouchUV
• llDetectedTouchPos
• llDetectedTouchNormal
• llDetectedTouchBinormal

Deep Notes
History
• Introduced in Viewer SVN:870 r92872 Branch:Release Wednesday, 23 July 2008.
• Server support available in Second Life Server 1.24.7.98039, client support in Release Candidate viewer 1.21.4 (98167)